mirror of
https://github.com/eworm-de/routeros-scripts.git
synced 2024-05-11 05:55:19 +00:00
49 lines
1.9 KiB
Plaintext
49 lines
1.9 KiB
Plaintext
#!rsc by RouterOS
|
|
# RouterOS script: certificate-renew-issued
|
|
# Copyright (c) 2019-2024 Christian Hesse <mail@eworm.de>
|
|
# https://git.eworm.de/cgit/routeros-scripts/about/COPYING.md
|
|
#
|
|
# requires RouterOS, version=7.12
|
|
#
|
|
# renew locally issued certificates
|
|
# https://git.eworm.de/cgit/routeros-scripts/about/doc/certificate-renew-issued.md
|
|
|
|
:global GlobalFunctionsReady;
|
|
:while ($GlobalFunctionsReady != true) do={ :delay 500ms; }
|
|
|
|
:do {
|
|
:local ScriptName [ :jobname ];
|
|
|
|
:global CertIssuedExportPass;
|
|
|
|
:global LogPrint;
|
|
:global MkDir;
|
|
:global ScriptLock;
|
|
|
|
:if ([ $ScriptLock $ScriptName ] = false) do={
|
|
:error false;
|
|
}
|
|
|
|
:foreach Cert in=[ /certificate/find where issued expires-after<3w ] do={
|
|
:local CertVal [ /certificate/get $Cert ];
|
|
/certificate/issued-revoke $Cert;
|
|
/certificate/set name=($CertVal->"name" . "-revoked-" . [ /system/clock/get date ]) $Cert;
|
|
/certificate/add name=($CertVal->"name") common-name=($CertVal->"common-name") \
|
|
key-usage=($CertVal->"key-usage") subject-alt-name=($CertVal->"subject-alt-name");
|
|
/certificate/sign ($CertVal->"name") ca=($CertVal->"ca");
|
|
:if ([ :typeof ($CertIssuedExportPass->($CertVal->"common-name")) ] = "str") do={
|
|
:if ([ $MkDir "cert-issued" ] = true) do={
|
|
/certificate/export-certificate ($CertVal->"name") type=pkcs12 \
|
|
file-name=("cert-issued/" . $CertVal->"common-name") \
|
|
export-passphrase=($CertIssuedExportPass->($CertVal->"common-name"));
|
|
$LogPrint info $ScriptName ("Issued a new certificate for \"" . $CertVal->"common-name" . \
|
|
"\", exported to \"cert-issued/" . $CertVal->"common-name" . ".p12\".");
|
|
} else={
|
|
$LogPrint warning $ScriptName ("Failed creating directory, not exporting certificate.");
|
|
}
|
|
} else={
|
|
$LogPrint info $ScriptName ("Issued a new certificate for \"" . $CertVal->"common-name" . "\".");
|
|
}
|
|
}
|
|
} on-error={ }
|