mirror of
https://github.com/eworm-de/routeros-scripts.git
synced 2024-05-11 05:55:19 +00:00
ceaa83b83e
... and fix logging. Logging with severity from variable (:log $severity ...) is not possible, this is considered a syntax error. Also the 'workaround' with parsing code failed with missing message in log. The reliable code is a lot longer, so merge the two functions to save a lot of duplicate code.
39 lines
1.5 KiB
Plaintext
39 lines
1.5 KiB
Plaintext
#!rsc
|
|
# RouterOS script: ipv6-update
|
|
# Copyright (c) 2013-2020 Christian Hesse <mail@eworm.de>
|
|
#
|
|
# update firewall and dns settings on IPv6 prefix change
|
|
|
|
:local PdPrefix $"pd-prefix";
|
|
|
|
:global ParseKeyValueStore;
|
|
:global LogPrintExit;
|
|
|
|
:if ([ :typeof $PdPrefix ] = "nothing") do={
|
|
$LogPrintExit error "This script is supposed to run from ipv6 dhcp-client." true;
|
|
}
|
|
|
|
:local Pool [ / ipv6 pool get [ find where prefix=$PdPrefix ] name ];
|
|
:local AddrList [ / ipv6 firewall address-list find where comment=("ipv6-pool-" . $Pool) ];
|
|
:local OldPrefix [ / ipv6 firewall address-list get $AddrList address ];
|
|
|
|
# give the interfaces a moment to receive their addresses
|
|
:delay 2s;
|
|
|
|
if ($OldPrefix != $PdPrefix) do={
|
|
:log info ("Updating IPv6 address list with new IPv6 prefix " . $PdPrefix);
|
|
/ ipv6 firewall address-list set address=$PdPrefix $AddrList;
|
|
|
|
:foreach Record in=[ / ip dns static find where comment~("^ipv6-pool-" . $Pool . ",") ] do={
|
|
:local RecordVal [ / ip dns static get $Record ];
|
|
:local Comment [ $ParseKeyValueStore ($RecordVal->"comment") ];
|
|
|
|
:local Prefix [ / ipv6 address get [ find where interface=($Comment->"interface") from-pool=$Pool global ] address ];
|
|
:set Prefix [ :toip6 [ :pick $Prefix 0 [ :find $Prefix "/64" ] ] ];
|
|
:local Address ($Prefix | ([ :toip6 ($RecordVal->"address") ] & ::ffff:ffff:ffff:ffff));
|
|
|
|
:log info ("Updating DNS record for " . ($RecordVal->"name") . ($RecordVal->"regexp") . " to " . $Address);
|
|
/ ip dns static set address=$Address $Record;
|
|
}
|
|
}
|